home *** CD-ROM | disk | FTP | other *** search
/ MacWorld 2000 January / Macworld (2000-01).dmg / QuarkXPress 4.10 update / Documents / Apple Events Scripting / Document Construction < prev   
Text File  |  1999-07-26  |  6KB  |  186 lines
  1. tell application "QuarkXPress"
  2.     activate
  3.     set thepath to (choose folder with prompt "Select the Sample " & ¬
  4.         "Documents folder inside the Apple Events Scripting folder of " & ¬
  5.         "your QuarkXPress folder:") as text
  6.     
  7.     tell default document 1
  8.         set oldHeight to page height
  9.         set oldWidth to page width
  10.         set oldAutoTextBox to automatic text box
  11.         set oldGuidesShowing to guides showing
  12.         set xDocMeasure to horizontal measure
  13.         set yDocMeasure to vertical measure
  14.         set page height to "30 cm"
  15.         set page width to "34 cm"
  16.         set automatic text box to false
  17.         set guides showing to true
  18.         set guides in front to true
  19.         set horizontal measure to centimeters
  20.         set vertical measure to centimeters
  21.     end tell
  22.     make document at beginning
  23.     
  24.     tell document 1
  25.         set view scale to fit page in window
  26.     end tell
  27.     
  28.     --CREATE GUIDES TO LAYOUT ELEMENTS ON THE PAGE
  29.     tell page 1 of document 1
  30.         make horizontal guide at beginning with properties {position:¬
  31.             "4.218 cm"}
  32.         make horizontal guide at end with properties {position:"8.447 cm"}
  33.         make horizontal guide at beginning with properties {position:¬
  34.             "27.152 cm"}
  35.         make vertical guide at end with properties {position:"2 cm"}
  36.         make vertical guide at end with properties {position:"4.962 cm"}
  37.         make vertical guide at end with properties {position:"18.742 cm"}
  38.         make vertical guide at end with properties {position:"32 cm"}
  39.     end tell
  40.     
  41.     --CREATE FIRST TEXT BOX.
  42.     tell page 1 of document 1
  43.         make text box at beginning with properties {bounds:{"2 cm", "5 cm", "8 cm", "19 cm"}}
  44.         tell text box 1
  45.             set vertical justification to bottom justified
  46.             set color to "none"
  47.         end tell
  48.     end tell
  49.     
  50.     tell story 1 of text box 1 of page 1 of document 1
  51.         set contents of it to "Biking Gear"
  52.         set font to "Times"
  53.         set size of word 1 to 30
  54.         set style of word 1 to all caps
  55.         set base shift of word 1 to 60
  56.         set track of word 1 to 50
  57.         set kern of last character of word 1 to -100
  58.         set size of word 2 to 120
  59.         set color of word 2 to "Blue"
  60.         set style of word 2 to italic
  61.         set kern of character 1 of word 2 to -5
  62.         set kern of character 2 of word 2 to -5
  63.     end tell
  64.     
  65.     --CREATE SECOND TEXT BOX.
  66.     tell page 1 of document 1
  67.         make text box at end with properties {bounds:{"8.5 cm", "5 cm", "29.959 cm", "18.472 cm"}}
  68.         tell text box 2
  69.             try
  70.                 set story 1 to alias (thepath & "ASB Text")
  71.             on error
  72.                 set story 1 to (choose file with prompt "Please select the file \"ASB Text.\"" of type {"TEXT"})
  73.             end try
  74.             set size of story 1 to 11
  75.             set leading of story 1 to 43
  76.             set justification of story 1 to full
  77.             set font of story 1 to "Times"
  78.         end tell
  79.         tell paragraph 1 of story 1 of text box 2
  80.             set drop cap characters to 1
  81.             set drop cap lines to 3
  82.             set color of character 1 of word 1 to "Blue"
  83.         end tell
  84.         tell last paragraph of story 1 of text box 2
  85.             set color of character 1 of word 1 to "Blue"
  86.             set size of character 1 of word 1 to 28
  87.             set rule on of rule above to true
  88.             set text length of rule above to false
  89.             set width of rule above to 0.5
  90.             set position of rule above to "1 cm"
  91.             set color of rule above to "Cyan"
  92.             set shade of rule above to 100
  93.         end tell
  94.     end tell
  95.     
  96.     --CREATE FIRST PICTURE BOX.
  97.     tell page 1 of document 1
  98.         make picture box at beginning with properties ¬
  99.             {bounds:{"10.386 cm", "20.758 cm", "27.636 cm", ¬
  100.                 "33.508 cm"}, color:"None"}
  101.         tell picture box 1
  102.             set rotation to -25
  103.             try
  104.                 set image 1 to alias (thepath & "Shirts.TIFF")
  105.             on error
  106.                 set image 1 to (choose file with prompt "Please select the file \"Shirts.TIFF.\"" of type {"TIFF"})
  107.             end try
  108.             tell image 1
  109.                 set scale to {"115", "115"}
  110.             end tell
  111.         end tell
  112.     end tell
  113.     
  114.     --CREATE SECOND PICTURE BOX.
  115.     tell page 1 of document 1
  116.         make picture box at end with properties {bounds:¬
  117.             {"8.471 cm", "2 cm", "9.971 cm", "3.5 cm"}, color:"None"}
  118.         tell picture box 2
  119.             try
  120.                 set image 1 to alias (thepath & "Glove.TIFF")
  121.             on error
  122.                 set image 1 to (choose file with prompt "Please select the file \"Glove.TIFF.\"" of type {"TIFF"})
  123.             end try
  124.             set bounds of image 1 to exact fit
  125.         end tell
  126.         duplicate picture box 2 to after picture box 2
  127.         tell picture box 3
  128.             set bounds to {"12.471 cm", "2 cm", "13.971 cm", "3.5 cm"}
  129.         end tell
  130.         duplicate picture box 2 to after picture box 3
  131.         tell picture box 4
  132.             set bounds to {"16.471 cm", "2 cm", "17.971 cm", "3.5 cm"}
  133.         end tell
  134.         duplicate picture box 2 to after picture box 4
  135.         tell picture box 5
  136.             set bounds to {"20.471 cm", "2 cm", "21.971 cm", "3.5 cm"}
  137.         end tell
  138.     end tell
  139.     
  140.     --CREATE THIRD PICTURE BOX.
  141.     tell page 1 of document 1
  142.         make picture box at end with properties {bounds:{"6.875 cm", ¬
  143.             "18.425 cm", "12.729 cm", "26.4 cm"}, color:"None"}
  144.         tell picture box 6
  145.             try
  146.                 set image 1 to alias (thepath & "Helmet.TIFF")
  147.             on error
  148.                 set image 1 to (choose file with prompt "Please select " & ¬
  149.                     "the file \"Helmet.TIFF\"" of type {"TIFF"})
  150.             end try
  151.             tell image 1
  152.                 set scale to {"70", "70"}
  153.                 set offset to {"0.557 cm", "1.254 cm"}
  154.             end tell
  155.         end tell
  156.     end tell
  157.     
  158.     --CREATE LINES
  159.     tell page 1 of document 1
  160.         make line box at end with properties {left point:¬
  161.             {"0 cm", "21.406 cm"}, right point:{"8 cm", "21.406 cm"}}
  162.         tell line box 1
  163.             set color to "Magenta"
  164.             set width to 3
  165.             set style to dotted
  166.         end tell
  167.         make line box at end
  168.         tell line box 2
  169.             set left point to {"8 cm", "2 cm"}
  170.             set right point to {"8 cm", "32 cm"}
  171.             set width to 0.5
  172.         end tell
  173.     end tell
  174.     
  175.     set guides showing of document 1 to false
  176.     save document 1 in (thepath & "Constructed Document")
  177.     
  178.     tell default document 1
  179.         set page height to oldHeight
  180.         set page width to oldWidth
  181.         set automatic text box to oldAutoTextBox
  182.         set guides showing to oldGuidesShowing
  183.         set horizontal measure to xDocMeasure
  184.         set vertical measure to yDocMeasure
  185.     end tell
  186. end tell